mirror of
https://github.com/pseXperiments/freedit.git
synced 2026-01-08 23:28:04 -05:00
479e295499
* chore: move rs code into `apps/server` * chore: scaffold vite/react app * feat: render raw html served by rust server in react app * chore: use `just` as tasks runner * doc: add main README * fix `dev-client` just script * refactor: write default config dirs relatively to exec bin
42 lines
777 B
Makefile
42 lines
777 B
Makefile
export PATH := "./node_modules/.bin:" + env_var('PATH')
|
|
|
|
default:
|
|
@just --choose
|
|
|
|
build:
|
|
#!/usr/bin/env -S parallel --shebang --ungroup --jobs {{ num_cpus() }}
|
|
just build-client
|
|
just build-server
|
|
|
|
[working-directory: 'apps/client']
|
|
build-client:
|
|
@bun tsc -b
|
|
bun vite build
|
|
|
|
[working-directory: 'apps/server']
|
|
build-server:
|
|
@cargo build -r
|
|
|
|
clean-server:
|
|
@rm -fr apps/server/{config.toml,freedit.db,snapshots,static/imgs,tantivy,target}
|
|
|
|
dev:
|
|
@just dev-client & just dev-server
|
|
|
|
[working-directory: 'apps/client']
|
|
dev-client:
|
|
@bun vite dev
|
|
|
|
[working-directory: 'apps/server']
|
|
dev-server:
|
|
@cargo run
|
|
|
|
start:
|
|
@just start-server & just start-client
|
|
|
|
start-server:
|
|
@./apps/server/target/release/freedit
|
|
|
|
start-client:
|
|
@vite preview
|