Move Project::replace to Workspace

src/workspace.coffee

@@ -835,3 +835,44 @@ class Workspace extends Model
       task.terminate()
       deferred.resolve('cancelled')
     promise
+
+  # Public: Performs a replace across all the specified files in the project.
+  #
+  # * `regex` A {RegExp} to search with.
+  # * `replacementText` Text to replace all matches of regex with
+  # * `filePaths` List of file path strings to run the replace on.
+  # * `iterator` A {Function} callback on each file with replacements:
+  #   * `options` {Object} with keys `filePath` and `replacements`
+  #
+  # Returns a `Promise`.
+  replace: (regex, replacementText, filePaths, iterator) ->
+    deferred = Q.defer()
+
+    openPaths = (buffer.getPath() for buffer in atom.project.getBuffers())
+    outOfProcessPaths = _.difference(filePaths, openPaths)
+
+    inProcessFinished = !openPaths.length
+    outOfProcessFinished = !outOfProcessPaths.length
+    checkFinished = ->
+      deferred.resolve() if outOfProcessFinished and inProcessFinished
+
+    unless outOfProcessFinished.length
+      flags = 'g'
+      flags += 'i' if regex.ignoreCase
+
+      task = Task.once require.resolve('./replace-handler'), outOfProcessPaths, regex.source, flags, replacementText, ->
+        outOfProcessFinished = true
+        checkFinished()
+
+      task.on 'replace:path-replaced', iterator
+      task.on 'replace:file-error', (error) -> iterator(null, error)
+
+    for buffer in atom.project.getBuffers()
+      continue unless buffer.getPath() in filePaths
+      replacements = buffer.replace(regex, replacementText, iterator)
+      iterator({filePath: buffer.getPath(), replacements}) if replacements
+
+    inProcessFinished = true
+    checkFinished()
+
+    deferred.promise