mirror of
https://github.com/atom/atom.git
synced 2026-02-15 00:55:14 -05:00
08a27cf93d
TextMatePackage is only designed to load resources out of a TextMate bundle. It's used only at load time, and from that point out we only refer to our own global `syntax` data structure to access the data that it loads.
81 lines
2.8 KiB
CoffeeScript
81 lines
2.8 KiB
CoffeeScript
Package = require 'package'
|
|
fs = require 'fs'
|
|
plist = require 'plist'
|
|
_ = require 'underscore'
|
|
TextMateGrammar = require 'text-mate-grammar'
|
|
|
|
module.exports =
|
|
class TextMatePackage extends Package
|
|
@testName: (packageName) ->
|
|
/(\.|_|-)tmbundle$/.test(packageName)
|
|
|
|
@cssSelectorFromScopeSelector: (scopeSelector) ->
|
|
scopeSelector.split(', ').map((commaFragment) ->
|
|
commaFragment.split(' ').map((spaceFragment) ->
|
|
spaceFragment.split('.').map((dotFragment) ->
|
|
'.' + dotFragment.replace(/\+/g, '\\+')
|
|
).join('')
|
|
).join(' ')
|
|
).join(', ')
|
|
|
|
constructor: ->
|
|
super
|
|
@preferencesPath = fs.join(@path, "Preferences")
|
|
@syntaxesPath = fs.join(@path, "Syntaxes")
|
|
|
|
getGrammars: ->
|
|
return @grammars if @grammars
|
|
@grammars = []
|
|
if fs.exists(@syntaxesPath)
|
|
for grammarPath in fs.list(@syntaxesPath)
|
|
try
|
|
@grammars.push TextMateGrammar.loadFromPath(grammarPath)
|
|
catch e
|
|
console.warn "Failed to load grammar at path '#{grammarPath}'", e.stack
|
|
@grammars
|
|
|
|
getScopedProperties: ->
|
|
scopedProperties = []
|
|
|
|
for grammar in @getGrammars()
|
|
if properties = @propertiesFromTextMateSettings(grammar)
|
|
selector = @cssSelectorFromScopeSelector(grammar.scopeName)
|
|
scopedProperties.push({selector, properties})
|
|
|
|
for {scope, settings} in @getTextMatePreferenceObjects()
|
|
if properties = @propertiesFromTextMateSettings(settings)
|
|
selector = @cssSelectorFromScopeSelector(scope) if scope?
|
|
scopedProperties.push({selector, properties})
|
|
|
|
scopedProperties
|
|
|
|
getTextMatePreferenceObjects: ->
|
|
preferenceObjects = []
|
|
if fs.exists(@preferencesPath)
|
|
for preferencePath in fs.list(@preferencesPath)
|
|
plist.parseString fs.read(preferencePath), (e, data) =>
|
|
if e
|
|
console.warn "Failed to parse preference at path '#{preferencePath}'", e.stack
|
|
else
|
|
preferenceObjects.push(data[0])
|
|
preferenceObjects
|
|
|
|
propertiesFromTextMateSettings: (textMateSettings) ->
|
|
if textMateSettings.shellVariables
|
|
shellVariables = {}
|
|
for {name, value} in textMateSettings.shellVariables
|
|
shellVariables[name] = value
|
|
textMateSettings.shellVariables = shellVariables
|
|
|
|
editorProperties = _.compactObject(
|
|
commentStart: _.valueForKeyPath(textMateSettings, 'shellVariables.TM_COMMENT_START')
|
|
commentEnd: _.valueForKeyPath(textMateSettings, 'shellVariables.TM_COMMENT_END')
|
|
increaseIndentPattern: textMateSettings.increaseIndentPattern
|
|
decreaseIndentPattern: textMateSettings.decreaseIndentPattern
|
|
foldEndPattern: textMateSettings.foldingStopMarker
|
|
)
|
|
{ editor: editorProperties } if _.size(editorProperties) > 0
|
|
|
|
cssSelectorFromScopeSelector: (scopeSelector) ->
|
|
@constructor.cssSelectorFromScopeSelector(scopeSelector)
|