mirror of
https://github.com/atom/atom.git
synced 2026-04-28 03:01:47 -04:00
56677e71e4
I think this makes more sense then running them via a separate command, since that command would only make sense for atom-core, unlike the current 'run-package-specs' command, which works for any atom package. This way, they won't run by default, but you can opt in to running them on the command line by setting an env var, or in the spec runner by temporarily editing the code, like we do for focused tests anyway.
108 lines
3.8 KiB
CoffeeScript
108 lines
3.8 KiB
CoffeeScript
# These tests are excluded by default. To run them from the command line:
|
|
#
|
|
# ATOM_INTEGRATION_TESTS_ENABLED=true apm test
|
|
return unless process.env.ATOM_INTEGRATION_TESTS_ENABLED
|
|
|
|
os = require "os"
|
|
fs = require "fs"
|
|
path = require "path"
|
|
remote = require "remote"
|
|
temp = require("temp").track()
|
|
{spawn, spawnSync} = require "child_process"
|
|
{Builder, By} = require "../../build/node_modules/selenium-webdriver"
|
|
|
|
AtomPath = remote.process.argv[0]
|
|
AtomLauncherPath = path.join(__dirname, "helpers", "atom-launcher.sh")
|
|
SocketPath = path.join(os.tmpdir(), "atom-integration-test.sock")
|
|
ChromeDriverPort = 9515
|
|
|
|
describe "Starting Atom", ->
|
|
[chromeDriver, driver, tempDirPath] = []
|
|
|
|
beforeEach ->
|
|
tempDirPath = temp.mkdirSync("empty-dir")
|
|
|
|
waitsFor "chromedriver to start", (done) ->
|
|
chromeDriver = spawn "chromedriver", ["--verbose", "--port=#{ChromeDriverPort}"]
|
|
chromeDriver.on "error", (error) ->
|
|
throw new Error("chromedriver failed to start: #{error.message}")
|
|
chromeDriver.stderr.on "data", -> done()
|
|
|
|
afterEach ->
|
|
waitsForPromise -> driver.quit().thenFinally(-> chromeDriver.kill())
|
|
|
|
startAtom = (args...) ->
|
|
driver = new Builder()
|
|
.usingServer("http://localhost:#{ChromeDriverPort}")
|
|
.withCapabilities(
|
|
chromeOptions:
|
|
binary: AtomLauncherPath
|
|
args: [
|
|
"atom-path=#{AtomPath}"
|
|
"atom-args=#{args.join(" ")}"
|
|
"dev"
|
|
"safe"
|
|
"user-data-dir=#{temp.mkdirSync('integration-spec-')}"
|
|
"socket-path=#{SocketPath}"
|
|
]
|
|
)
|
|
.forBrowser('atom')
|
|
.build()
|
|
|
|
waitsForPromise ->
|
|
driver.wait ->
|
|
driver.getTitle().then (title) -> title.indexOf("Atom") >= 0
|
|
|
|
startAnotherAtom = (args...) ->
|
|
spawnSync(AtomPath, args.concat([
|
|
"--dev",
|
|
"--safe",
|
|
"--socket-path=#{SocketPath}"
|
|
]))
|
|
|
|
describe "when given the name of a file that doesn't exist", ->
|
|
tempFilePath = null
|
|
|
|
beforeEach ->
|
|
tempFilePath = path.join(tempDirPath, "an-existing-file")
|
|
fs.writeFileSync(tempFilePath, "This was already here.")
|
|
startAtom(path.join(tempDirPath, "new-file"))
|
|
|
|
it "opens a new window with an empty text editor", ->
|
|
waitsForPromise ->
|
|
driver.getAllWindowHandles().then (handles) ->
|
|
expect(handles.length).toBe 1
|
|
driver.executeScript(-> atom.workspace.getActivePane().getItems().length).then (length) ->
|
|
expect(length).toBe 1
|
|
driver.executeScript(-> atom.workspace.getActiveTextEditor().getText()).then (text) ->
|
|
expect(text).toBe("")
|
|
driver.findElement(By.tagName("atom-text-editor")).sendKeys("Hello world!")
|
|
driver.executeScript(-> atom.workspace.getActiveTextEditor().getText()).then (text) ->
|
|
expect(text).toBe "Hello world!"
|
|
|
|
# Opening another existing file in the same directory reuses the window,
|
|
# and opens a new tab for the file.
|
|
waitsForPromise ->
|
|
startAnotherAtom(tempFilePath)
|
|
driver.wait ->
|
|
driver.executeScript(-> atom.workspace.getActivePane().getItems().length).then (length) ->
|
|
length is 2
|
|
driver.executeScript(-> atom.workspace.getActiveTextEditor().getText()).then (text) ->
|
|
expect(text).toBe "This was already here."
|
|
|
|
# Opening a different directory creates a new window.
|
|
waitsForPromise ->
|
|
startAnotherAtom(temp.mkdirSync("another-empty-dir"))
|
|
driver.wait ->
|
|
driver.getAllWindowHandles().then (handles) ->
|
|
handles.length is 2
|
|
|
|
describe "when given the name of a directory that exists", ->
|
|
beforeEach ->
|
|
startAtom(tempDirPath)
|
|
|
|
it "opens a new window no text editors open", ->
|
|
waitsForPromise ->
|
|
driver.executeScript(-> atom.workspace.getActiveTextEditor()).then (editor) ->
|
|
expect(editor).toBeNull()
|