mirror of
https://github.com/microsoft/autogen.git
synced 2026-04-20 03:02:16 -04:00
d6b917faf4
* big bang gitub workflows * add missing settings in local.settings.json * config refactor * fix devlead plan response * swap cosmos to table storage for metadata storage * unify config via options * azd-ify WIP * add qdrant bicep WIP * working azd provision setup * consolidate SK version in projects * replace localhost :) * add fqdn to options * httpclient fixes * add managed identity to the function and assign contrib role * qdrant endpoint setting * add container instances cleanup code + wait on termination to upload to Github * formatting fixes * add tables in bicep * local getting started WIP * add azure setup instructions * add the load-waf bits * docs WIP --------- Co-authored-by: Kosta Petan <Kosta.Petan@microsoft.com>
83 lines
2.3 KiB
Bicep
83 lines
2.3 KiB
Bicep
param name string
|
|
param location string = resourceGroup().location
|
|
param tags object = {}
|
|
|
|
@description('Indicates whether admin user is enabled')
|
|
param adminUserEnabled bool = false
|
|
|
|
@description('Indicates whether anonymous pull is enabled')
|
|
param anonymousPullEnabled bool = false
|
|
|
|
@description('Indicates whether data endpoint is enabled')
|
|
param dataEndpointEnabled bool = false
|
|
|
|
@description('Encryption settings')
|
|
param encryption object = {
|
|
status: 'disabled'
|
|
}
|
|
|
|
@description('Options for bypassing network rules')
|
|
param networkRuleBypassOptions string = 'AzureServices'
|
|
|
|
@description('Public network access setting')
|
|
param publicNetworkAccess string = 'Enabled'
|
|
|
|
@description('SKU settings')
|
|
param sku object = {
|
|
name: 'Basic'
|
|
}
|
|
|
|
@description('Zone redundancy setting')
|
|
param zoneRedundancy string = 'Disabled'
|
|
|
|
@description('The log analytics workspace ID used for logging and monitoring')
|
|
param workspaceId string = ''
|
|
|
|
// 2022-02-01-preview needed for anonymousPullEnabled
|
|
resource containerRegistry 'Microsoft.ContainerRegistry/registries@2022-02-01-preview' = {
|
|
name: name
|
|
location: location
|
|
tags: tags
|
|
sku: sku
|
|
properties: {
|
|
adminUserEnabled: adminUserEnabled
|
|
anonymousPullEnabled: anonymousPullEnabled
|
|
dataEndpointEnabled: dataEndpointEnabled
|
|
encryption: encryption
|
|
networkRuleBypassOptions: networkRuleBypassOptions
|
|
publicNetworkAccess: publicNetworkAccess
|
|
zoneRedundancy: zoneRedundancy
|
|
}
|
|
}
|
|
|
|
// TODO: Update diagnostics to be its own module
|
|
// Blocking issue: https://github.com/Azure/bicep/issues/622
|
|
// Unable to pass in a `resource` scope or unable to use string interpolation in resource types
|
|
resource diagnostics 'Microsoft.Insights/diagnosticSettings@2021-05-01-preview' = if (!empty(workspaceId)) {
|
|
name: 'registry-diagnostics'
|
|
scope: containerRegistry
|
|
properties: {
|
|
workspaceId: workspaceId
|
|
logs: [
|
|
{
|
|
category: 'ContainerRegistryRepositoryEvents'
|
|
enabled: true
|
|
}
|
|
{
|
|
category: 'ContainerRegistryLoginEvents'
|
|
enabled: true
|
|
}
|
|
]
|
|
metrics: [
|
|
{
|
|
category: 'AllMetrics'
|
|
enabled: true
|
|
timeGrain: 'PT1M'
|
|
}
|
|
]
|
|
}
|
|
}
|
|
|
|
output loginServer string = containerRegistry.properties.loginServer
|
|
output name string = containerRegistry.name
|