nim-libp2p/libp2p/protocols/pubsub/pubsubpeer.nim

# Nim-LibP2P
# Copyright (c) 2023 Status Research & Development GmbH
# Licensed under either of
#  * Apache License, version 2.0, ([LICENSE-APACHE](LICENSE-APACHE))
#  * MIT license ([LICENSE-MIT](LICENSE-MIT))
# at your option.
# This file may not be copied, modified, or distributed except according to
# those terms.

{.push raises: [].}

import std/[sequtils, tables, hashes, options, sets, deques]
import results
import chronos, chronicles, nimcrypto/sha2, metrics
import chronos/ratelimit
import
  rpc/[messages, message, protobuf],
  ../../peerid,
  ../../peerinfo,
  ../../stream/connection,
  ../../crypto/crypto,
  ../../protobuf/minprotobuf,
  ../../utility,
  ../../utils/sequninit,
  ./bandwidth

when defined(libp2p_gossipsub_1_4):
  import ./bandwidth

export peerid, connection, deques

logScope:
  topics = "libp2p pubsubpeer"

when defined(libp2p_expensive_metrics):
  declareCounter(
    libp2p_pubsub_sent_messages, "number of messages sent", labels = ["id", "topic"]
  )
  declareCounter(
    libp2p_pubsub_skipped_received_messages,
    "number of received skipped messages",
    labels = ["id"],
  )
  declareCounter(
    libp2p_pubsub_skipped_sent_messages,
    "number of sent skipped messages",
    labels = ["id"],
  )

when defined(pubsubpeer_queue_metrics):
  declareGauge(
    libp2p_gossipsub_priority_queue_size,
    "the number of messages in the priority queue",
    labels = ["id"],
  )
  declareGauge(
    libp2p_gossipsub_non_priority_queue_size,
    "the number of messages in the non-priority queue",
    labels = ["id"],
  )

declareCounter(
  libp2p_pubsub_disconnects_over_non_priority_queue_limit,
  "number of peers disconnected due to over non-prio queue capacity",
)

const DefaultMaxNumElementsInNonPriorityQueue* = 1024

type
  PeerRateLimitError* = object of CatchableError

  GetConnDialError* = object of CatchableError

  PubSubObserver* = ref object
    onRecv*: proc(peer: PubSubPeer, msgs: var RPCMsg) {.gcsafe, raises: [].}
    onSend*: proc(peer: PubSubPeer, msgs: var RPCMsg) {.gcsafe, raises: [].}
    onValidated*:
      proc(peer: PubSubPeer, msg: Message, msgId: MessageId) {.gcsafe, raises: [].}

  PubSubPeerEventKind* {.pure.} = enum
    StreamOpened
    StreamClosed
    DisconnectionRequested
      # tells gossipsub that the transport connection to the peer should be closed

  PubSubPeerEvent* = object
    kind*: PubSubPeerEventKind

  GetConn* =
    proc(): Future[Connection] {.async: (raises: [CancelledError, GetConnDialError]).}
  DropConn* = proc(peer: PubSubPeer) {.gcsafe, raises: [].}
    # have to pass peer as it's unknown during init
  OnEvent* = proc(peer: PubSubPeer, event: PubSubPeerEvent) {.gcsafe, raises: [].}

  QueuedMessage = object
    # Messages sent as lower-priority are queued and sent in other location
    # in which we need to keep arguments like `useCustomConn`.
    data: seq[byte]
    useCustomConn: bool

  RpcMessageQueue* = ref object
    # Tracks async tasks for sending high-priority peer-published messages.
    sendPriorityQueue: Deque[Future[void]]
    # Queue for lower-priority messages, like "IWANT" replies and relay messages.
    nonPriorityQueue: AsyncQueue[QueuedMessage]
    # Task for processing non-priority message queue.
    sendNonPriorityTask: Future[void]

  CustomConnCreationProc* = proc(
    destAddr: Option[MultiAddress], destPeerId: PeerId, codec: string
  ): Connection {.gcsafe, raises: [].}

  CustomPeerSelectionProc* = proc(
    allPeers: HashSet[PubSubPeer],
    directPeers: HashSet[PubSubPeer],
    meshPeers: HashSet[PubSubPeer],
    fanoutPeers: HashSet[PubSubPeer],
  ): HashSet[PubSubPeer] {.gcsafe, raises: [].}

  CustomConnectionCallbacks* = object
    customConnCreationCB*: CustomConnCreationProc
    customPeerSelectionCB*: CustomPeerSelectionProc

  PubSubPeer* = ref object of RootObj
    getConn*: GetConn # callback to establish a new send connection
    onEvent*: OnEvent # Connectivity updates for peer
    codec*: string # the protocol that this peer joined from
    sendConn*: Connection # cached send connection
    connectedFut: Future[void]
    address*: Option[MultiAddress]
    peerId*: PeerId
    handler*: RPCHandler
    observers*: ref seq[PubSubObserver] # ref as in smart_ptr

    when defined(libp2p_gossipsub_1_4):
      bandwidthTracking*: BandwidthTracking

    score*: float64
    sentIHaves*: Deque[HashSet[MessageId]]
    iDontWants*: Deque[HashSet[SaltedId]]
      ## IDONTWANT contains unvalidated message id:s which may be long and/or
      ## expensive to look up, so we apply the same salting to them as during
      ## unvalidated message processing
    iHaveBudget*: int
    pingBudget*: int
    maxMessageSize: int
    appScore*: float64 # application specific score
    behaviourPenalty*: float64 # the eventual penalty score
    overheadRateLimitOpt*: Opt[TokenBucket]

    when defined(libp2p_gossipsub_1_4):
      preambleBudget*: int
      heIsReceivings*: Table[MessageId, uint32]
      heIsSendings*: Table[MessageId, Moment]

    rpcmessagequeue: RpcMessageQueue
    maxNumElementsInNonPriorityQueue*: int
      # The max number of elements allowed in the non-priority queue.
    disconnected: bool
    customConnCallbacks*: Option[CustomConnectionCallbacks]

  RPCHandler* =
    proc(peer: PubSubPeer, data: seq[byte]): Future[void] {.async: (raises: []).}

when defined(libp2p_agents_metrics):
  func shortAgent*(p: PubSubPeer): string =
    if p.sendConn.isNil or p.sendConn.getWrapped().isNil:
      "unknown"
    else:
      #TODO the sendConn is setup before identify,
      #so we have to read the parents short agent..
      p.sendConn.getWrapped().shortAgent

proc getAgent*(peer: PubSubPeer): string =
  return
    when defined(libp2p_agents_metrics):
      if peer.shortAgent.len > 0: peer.shortAgent else: "unknown"
    else:
      "unknown"

proc `$`*(p: PubSubPeer): string =
  $p.peerId

func hash*(p: PubSubPeer): Hash =
  p.peerId.hash

func `==`*(a, b: PubSubPeer): bool =
  a.peerId == b.peerId

func shortLog*(p: PubSubPeer): string =
  if p.isNil:
    "PubSubPeer(nil)"
  else:
    shortLog(p.peerId)
chronicles.formatIt(PubSubPeer):
  shortLog(it)

proc connected*(p: PubSubPeer): bool =
  not p.sendConn.isNil and not (p.sendConn.closed or p.sendConn.atEof)

proc hasObservers*(p: PubSubPeer): bool =
  p.observers != nil and anyIt(p.observers[], it != nil)

func outbound*(p: PubSubPeer): bool =
  # gossipsub 1.1 spec requires us to know if the transport is outgoing
  # in order to give priotity to connections we make
  # https://github.com/libp2p/specs/blob/master/pubsub/gossipsub/gossipsub-v1.1.md#outbound-mesh-quotas
  # This behaviour is presrcibed to counter sybil attacks and ensures that a coordinated inbound attack can never fully take over the mesh
  if not p.sendConn.isNil and p.sendConn.transportDir == Direction.Out: true else: false

proc recvObservers*(p: PubSubPeer, msg: var RPCMsg) =
  # trigger hooks
  if not (isNil(p.observers)) and p.observers[].len > 0:
    for obs in p.observers[]:
      if not (isNil(obs)): # TODO: should never be nil, but...
        if not (isNil(obs.onRecv)):
          obs.onRecv(p, msg)

proc validatedObservers*(p: PubSubPeer, msg: Message, msgId: MessageId) =
  # trigger hooks
  if not (isNil(p.observers)) and p.observers[].len > 0:
    for obs in p.observers[]:
      if not (isNil(obs.onValidated)):
        obs.onValidated(p, msg, msgId)

proc sendObservers(p: PubSubPeer, msg: var RPCMsg) =
  # trigger hooks
  if not (isNil(p.observers)) and p.observers[].len > 0:
    for obs in p.observers[]:
      if not (isNil(obs)): # TODO: should never be nil, but...
        if not (isNil(obs.onSend)):
          obs.onSend(p, msg)

proc handle*(p: PubSubPeer, conn: Connection) {.async: (raises: []).} =
  debug "starting pubsub read loop", conn, peer = p, closed = conn.closed
  try:
    try:
      while not conn.atEof:
        trace "waiting for data", conn, peer = p, closed = conn.closed

        var data = await conn.readLp(p.maxMessageSize)
        trace "read data from peer",
          conn, peer = p, closed = conn.closed, data = data.shortLog

        await p.handler(p, data)
        data = newSeqUninit[byte](0) # Release memory
    except PeerRateLimitError as exc:
      debug "Peer rate limit exceeded, exiting read while",
        conn, peer = p, description = exc.msg
    except LPStreamError as exc:
      debug "Exception occurred in PubSubPeer.handle",
        conn, peer = p, closed = conn.closed, description = exc.msg
    finally:
      await conn.close()
  except CancelledError as e:
    # This is top-level procedure which will work as separate task, so it
    # do not need to propagate CancelledError.
    trace "Unexpected cancellation in PubSubPeer.handle", description = e.msg
  finally:
    debug "exiting pubsub read loop", conn, peer = p, closed = conn.closed

proc closeSendConn(
    p: PubSubPeer, event: PubSubPeerEventKind
) {.async: (raises: [CancelledError]).} =
  if p.sendConn != nil:
    trace "Removing send connection", p, conn = p.sendConn
    await p.sendConn.close()
    p.sendConn = nil

  if not p.connectedFut.finished:
    p.connectedFut.complete()

  try:
    if p.onEvent != nil:
      p.onEvent(p, PubSubPeerEvent(kind: event))
  except CancelledError as exc:
    raise exc
  # don't cleanup p.address else we leak some gossip stat table

proc connectOnce(
    p: PubSubPeer
): Future[void] {.async: (raises: [CancelledError, GetConnDialError, LPError]).} =
  try:
    if p.connectedFut.finished:
      p.connectedFut = newFuture[void]()
    let newConn =
      try:
        await p.getConn().wait(5.seconds)
      except AsyncTimeoutError as error:
        trace "getConn timed out", description = error.msg
        raise (ref LPError)(msg: "Cannot establish send connection: " & error.msg)

    # When the send channel goes up, subscriptions need to be sent to the
    # remote peer - if we had multiple channels up and one goes down, all
    # stop working so we make an effort to only keep a single channel alive

    trace "Get new send connection", p, newConn

    # Careful to race conditions here.
    # Topic subscription relies on either connectedFut
    # to be completed, or onEvent to be called later
    p.connectedFut.complete()
    p.sendConn = newConn
    p.address =
      if p.sendConn.observedAddr.isSome:
        some(p.sendConn.observedAddr.get)
      else:
        none(MultiAddress)

    if p.onEvent != nil:
      p.onEvent(p, PubSubPeerEvent(kind: PubSubPeerEventKind.StreamOpened))

    await handle(p, newConn)
  finally:
    await p.closeSendConn(PubSubPeerEventKind.StreamClosed)

proc connectImpl(p: PubSubPeer) {.async: (raises: []).} =
  try:
    # Keep trying to establish a connection while it's possible to do so - the
    # send connection might get disconnected due to a timeout or an unrelated
    # issue so we try to get a new on
    while true:
      if p.disconnected:
        if not p.connectedFut.finished:
          p.connectedFut.complete()
        return
      await connectOnce(p)
  except CancelledError as exc:
    debug "Could not establish send connection", description = exc.msg
  except LPError as exc:
    debug "Could not establish send connection", description = exc.msg
  except GetConnDialError as exc:
    debug "Could not establish send connection", description = exc.msg

proc connect*(p: PubSubPeer) =
  if p.connected:
    return

  asyncSpawn connectImpl(p)

proc hasSendConn*(p: PubSubPeer): bool =
  p.sendConn != nil

template sendMetrics(msg: RPCMsg): untyped =
  when defined(libp2p_expensive_metrics):
    for x in msg.messages:
      # metrics
      libp2p_pubsub_sent_messages.inc(labelValues = [$p.peerId, x.topic])

proc clearSendPriorityQueue(p: PubSubPeer) =
  if p.rpcmessagequeue.sendPriorityQueue.len == 0:
    return # fast path

  while p.rpcmessagequeue.sendPriorityQueue.len > 0 and
      p.rpcmessagequeue.sendPriorityQueue[0].finished:
    discard p.rpcmessagequeue.sendPriorityQueue.popFirst()

  while p.rpcmessagequeue.sendPriorityQueue.len > 0 and
      p.rpcmessagequeue.sendPriorityQueue[^1].finished:
    discard p.rpcmessagequeue.sendPriorityQueue.popLast()

  when defined(pubsubpeer_queue_metrics):
    libp2p_gossipsub_priority_queue_size.set(
      value = p.rpcmessagequeue.sendPriorityQueue.len.int64, labelValues = [$p.peerId]
    )

proc sendMsgContinue(conn: Connection, msgFut: Future[void]) {.async: (raises: []).} =
  # Continuation for a pending `sendMsg` future from below
  try:
    await msgFut
    trace "sent pubsub message to remote", conn
  except CatchableError as exc:
    trace "Unexpected exception in sendMsgContinue", conn, description = exc.msg
    # Next time sendConn is used, it will be have its close flag set and thus
    # will be recycled
    await conn.close() # This will clean up the send connection

proc sendMsgSlow(p: PubSubPeer, msg: seq[byte]) {.async: (raises: [CancelledError]).} =
  # Slow path of `sendMsg` where msg is held in memory while send connection is
  # being set up
  if p.sendConn == nil:
    # Wait for a send conn to be setup. `connectOnce` will
    # complete this even if the sendConn setup failed
    discard await race(p.connectedFut)

  var conn = p.sendConn
  if conn == nil or conn.closed():
    debug "No send connection", p, payload = shortLog(msg)
    return

  trace "sending encoded msg to peer", conn, encoded = shortLog(msg)
  await sendMsgContinue(conn, conn.writeLp(msg))

proc sendMsg(
    p: PubSubPeer, msg: seq[byte], useCustomConn: bool = false
): Future[void] {.async: (raises: []).} =
  type ConnectionType = enum
    ctCustom
    ctSend
    ctSlow

  var slowPath = false
  let (conn, connType) =
    if useCustomConn and p.customConnCallbacks.isSome:
      let address = p.address
      (
        p.customConnCallbacks.get().customConnCreationCB(address, p.peerId, p.codec),
        ctCustom,
      )
    elif p.sendConn != nil and not p.sendConn.closed():
      (p.sendConn, ctSend)
    else:
      slowPath = true
      (nil, ctSlow)

  if not slowPath:
    trace "sending encoded msg to peer",
      conntype = $connType, conn = conn, encoded = shortLog(msg)
    let f = conn.writeLp(msg)
    if not f.completed():
      sendMsgContinue(conn, f)
    else:
      f
  else:
    trace "sending encoded msg to peer via slow path"
    sendMsgSlow(p, msg)

proc sendEncoded*(
    p: PubSubPeer, msg: seq[byte], isHighPriority: bool, useCustomConn: bool = false
): Future[void] =
  ## Asynchronously sends an encoded message to a specified `PubSubPeer`.
  ##
  ## Parameters:
  ## - `p`: The `PubSubPeer` instance to which the message is to be sent.
  ## - `msg`: The message to be sent, encoded as a sequence of bytes (`seq[byte]`).
  ## - `isHighPriority`: A boolean indicating whether the message should be treated as high priority.
  ## High priority messages are sent immediately, while low priority messages are queued and sent only after all high
  ## priority messages have been sent.
  doAssert(not isNil(p), "pubsubpeer nil!")

  p.clearSendPriorityQueue()

  # When queues are empty, skipping the non-priority queue for low priority
  # messages reduces latency
  let emptyQueues =
    (
      p.rpcmessagequeue.sendPriorityQueue.len() +
      p.rpcmessagequeue.nonPriorityQueue.len()
    ) == 0

  if msg.len <= 0:
    debug "empty message, skipping", p, payload = shortLog(msg)
    Future[void].completed()
  elif msg.len > p.maxMessageSize:
    info "trying to send a msg too big for pubsub",
      maxSize = p.maxMessageSize, msgSize = msg.len
    Future[void].completed()
  elif isHighPriority or emptyQueues:
    let f = p.sendMsg(msg, useCustomConn)
    if not f.finished:
      p.rpcmessagequeue.sendPriorityQueue.addLast(f)
      when defined(pubsubpeer_queue_metrics):
        libp2p_gossipsub_priority_queue_size.inc(labelValues = [$p.peerId])
    f
  else:
    if len(p.rpcmessagequeue.nonPriorityQueue) >= p.maxNumElementsInNonPriorityQueue:
      if not p.disconnected:
        p.disconnected = true
        libp2p_pubsub_disconnects_over_non_priority_queue_limit.inc()
        p.closeSendConn(PubSubPeerEventKind.DisconnectionRequested)
      else:
        Future[void].completed()
    else:
      let f = p.rpcmessagequeue.nonPriorityQueue.addLast(
        QueuedMessage(data: msg, useCustomConn: useCustomConn)
      )
      when defined(pubsubpeer_queue_metrics):
        libp2p_gossipsub_non_priority_queue_size.inc(labelValues = [$p.peerId])
      f

iterator splitRPCMsg(
    peer: PubSubPeer, rpcMsg: RPCMsg, maxSize: int, anonymize: bool
): seq[byte] =
  ## This iterator takes an `RPCMsg` and sequentially repackages its Messages into new `RPCMsg` instances.
  ## Each new `RPCMsg` accumulates Messages until reaching the specified `maxSize`. If a single Message
  ## exceeds the `maxSize` when trying to fit into an empty `RPCMsg`, the latter is skipped as too large to send.
  ## Every constructed `RPCMsg` is then encoded, optionally anonymized, and yielded as a sequence of bytes.

  var currentRPCMsg = RPCMsg()
  var currentSize = 0

  for msg in rpcMsg.messages:
    let msgSize = byteSize(msg)

    # Check if adding the next message will exceed maxSize
    if currentSize + msgSize > maxSize:
      if msgSize > maxSize:
        warn "message too big to sent", peer, rpcMsg = shortLog(msg)
        continue # Skip this message

      trace "sending msg to peer", peer, rpcMsg = shortLog(currentRPCMsg)
      yield encodeRpcMsg(currentRPCMsg, anonymize)
      currentRPCMsg = RPCMsg()
      currentSize = 0

    currentRPCMsg.messages.add(msg)
    currentSize += msgSize

  # Check if there is a non-empty currentRPCMsg left to be added
  if currentRPCMsg.messages.len > 0:
    trace "sending msg to peer", peer, rpcMsg = shortLog(currentRPCMsg)
    yield encodeRpcMsg(currentRPCMsg, anonymize)

proc send*(
    p: PubSubPeer,
    msg: RPCMsg,
    anonymize: bool,
    isHighPriority: bool,
    useCustomConn: bool = false,
) {.raises: [].} =
  ## Asynchronously sends an `RPCMsg` to a specified `PubSubPeer` with an option for anonymization.
  ##
  ## Parameters:
  ## - `p`: The `PubSubPeer` instance to which the message is to be sent.
  ## - `msg`: The `RPCMsg` instance representing the message to be sent.
  ## - `anonymize`: A boolean flag indicating whether the message should be sent with anonymization.
  ## - `isHighPriority`: A boolean flag indicating whether the message should be treated as high priority.
  ## High priority messages are sent immediately, while low priority messages are queued and sent only after all high
  ## priority messages have been sent.
  # When sending messages, we take care to re-encode them with the right
  # anonymization flag to ensure that we're not penalized for sending invalid
  # or malicious data on the wire - in particular, re-encoding protects against
  # some forms of valid but redundantly encoded protobufs with unknown or
  # duplicated fields
  let encoded =
    if p.hasObservers():
      var mm = msg
      # trigger send hooks
      p.sendObservers(mm)
      sendMetrics(mm)
      encodeRpcMsg(mm, anonymize)
    else:
      # If there are no send hooks, we redundantly re-encode the message to
      # protobuf for every peer - this could easily be improved!
      sendMetrics(msg)
      encodeRpcMsg(msg, anonymize)

  # Messages should not exceed 90% of maxMessageSize. Guessing 10% protobuf overhead.
  let maxEncodedMsgSize = (p.maxMessageSize * 90) div 100

  if encoded.len > maxEncodedMsgSize and msg.messages.len > 1:
    for encodedSplitMsg in splitRPCMsg(p, msg, maxEncodedMsgSize, anonymize):
      asyncSpawn p.sendEncoded(encodedSplitMsg, isHighPriority, useCustomConn)
  else:
    # If the message size is within limits, send it as is
    trace "sending msg to peer", peer = p, rpcMsg = shortLog(msg)
    asyncSpawn p.sendEncoded(encoded, isHighPriority, useCustomConn)

proc canAskIWant*(p: PubSubPeer, msgId: MessageId): bool =
  for sentIHave in p.sentIHaves.mitems():
    if msgId in sentIHave:
      sentIHave.excl(msgId)
      return true
  return false

proc sendNonPriorityTask(p: PubSubPeer) {.async: (raises: [CancelledError]).} =
  while true:
    # we send non-priority messages only if there are no pending priority messages
    let msg = await p.rpcmessagequeue.nonPriorityQueue.popFirst()
    while p.rpcmessagequeue.sendPriorityQueue.len > 0:
      p.clearSendPriorityQueue()
      # waiting for the last future minimizes the number of times we have to
      # wait for something (each wait = performance cost) -
      # clearSendPriorityQueue ensures we're not waiting for an already-finished
      # future
      if p.rpcmessagequeue.sendPriorityQueue.len > 0:
        # `race` prevents `p.rpcmessagequeue.sendPriorityQueue[^1]` from being
        # cancelled when this task is cancelled
        discard await race(p.rpcmessagequeue.sendPriorityQueue[^1])
    when defined(pubsubpeer_queue_metrics):
      libp2p_gossipsub_non_priority_queue_size.dec(labelValues = [$p.peerId])
    await p.sendMsg(msg.data, msg.useCustomConn)

proc startSendNonPriorityTask(p: PubSubPeer) =
  debug "starting sendNonPriorityTask", p
  if p.rpcmessagequeue.sendNonPriorityTask.isNil:
    p.rpcmessagequeue.sendNonPriorityTask = p.sendNonPriorityTask()

proc stopSendNonPriorityTask*(p: PubSubPeer) =
  if not p.rpcmessagequeue.sendNonPriorityTask.isNil:
    debug "stopping sendNonPriorityTask", p
    p.rpcmessagequeue.sendNonPriorityTask.cancelSoon()
    p.rpcmessagequeue.sendNonPriorityTask = nil
    p.rpcmessagequeue.sendPriorityQueue.clear()
    p.rpcmessagequeue.nonPriorityQueue.clear()

    when defined(pubsubpeer_queue_metrics):
      libp2p_gossipsub_priority_queue_size.set(labelValues = [$p.peerId], value = 0)
      libp2p_gossipsub_non_priority_queue_size.set(labelValues = [$p.peerId], value = 0)

proc new(T: typedesc[RpcMessageQueue]): T =
  return T(
    sendPriorityQueue: initDeque[Future[void]](),
    nonPriorityQueue: newAsyncQueue[QueuedMessage](),
  )

proc new*(
    T: typedesc[PubSubPeer],
    peerId: PeerId,
    getConn: GetConn,
    onEvent: OnEvent,
    codec: string,
    maxMessageSize: int,
    maxNumElementsInNonPriorityQueue: int = DefaultMaxNumElementsInNonPriorityQueue,
    overheadRateLimitOpt: Opt[TokenBucket] = Opt.none(TokenBucket),
    customConnCallbacks: Option[CustomConnectionCallbacks] =
      none(CustomConnectionCallbacks),
): T =
  result = T(
    getConn: getConn,
    onEvent: onEvent,
    codec: codec,
    peerId: peerId,
    connectedFut: newFuture[void](),
    maxMessageSize: maxMessageSize,
    overheadRateLimitOpt: overheadRateLimitOpt,
    rpcmessagequeue: RpcMessageQueue.new(),
    maxNumElementsInNonPriorityQueue: maxNumElementsInNonPriorityQueue,
    customConnCallbacks: customConnCallbacks,
  )

  when defined(libp2p_gossipsub_1_4):
    result.bandwidthTracking =
      BandwidthTracking(download: ExponentialMovingAverage.init())

  result.sentIHaves.addFirst(default(HashSet[MessageId]))
  result.iDontWants.addFirst(default(HashSet[SaltedId]))
  result.startSendNonPriorityTask()