Bind meta-D to duplicate line below

Refs #134

spec/app/editor-spec.coffee

@@ -2523,3 +2523,46 @@ describe "Editor", ->
           editor.trigger 'editor:move-line-down'
           expect(buffer.lineForRow(1)).toBe '    if (items.length <= 1) return items;'
           expect(buffer.lineForRow(2)).toBe '  var sort = function(items) {'
+
+  describe "when editor:duplicate-line is triggered", ->
+    describe "where there is no selection", ->
+      describe "when the cursor isn't on a folded line", ->
+        it "duplicates the current line below and moves the cursor down one row", ->
+          editor.setCursorBufferPosition([0, 5])
+          editor.trigger 'editor:duplicate-line'
+          expect(buffer.lineForRow(0)).toBe 'var quicksort = function () {'
+          expect(buffer.lineForRow(1)).toBe 'var quicksort = function () {'
+          expect(editor.getCursorBufferPosition()).toEqual [1, 5]
+
+      describe "when the cursor is on a folded line", ->
+        it "duplicates the entire fold before and moves the cursor to the new fold", ->
+          editor.setCursorBufferPosition([4])
+          editor.foldCurrentRow()
+          editor.trigger 'editor:duplicate-line'
+          expect(editor.getCursorScreenPosition()).toEqual [5]
+          expect(editor.isFoldedAtScreenRow(4)).toBeTruthy()
+          expect(editor.isFoldedAtScreenRow(5)).toBeTruthy()
+          expect(buffer.lineForRow(8)).toBe '    while(items.length > 0) {'
+          expect(buffer.lineForRow(9)).toBe '      current = items.shift();'
+          expect(buffer.lineForRow(10)).toBe '      current < pivot ? left.push(current) : right.push(current);'
+          expect(buffer.lineForRow(11)).toBe '    }'
+
+      describe "when the cursor is on the last line and it doesn't have a trailing newline", ->
+        it "inserts a newline and the duplicated line", ->
+          editor.moveCursorToBottom()
+          editor.trigger 'editor:duplicate-line'
+          expect(buffer.lineForRow(12)).toBe '};'
+          expect(buffer.lineForRow(13)).toBe '};'
+          expect(buffer.lineForRow(14)).toBeUndefined()
+          expect(editor.getCursorBufferPosition()).toEqual [13, 2]
+
+      describe "when the cursor in on the last line and it is only a newline", ->
+        it "duplicates the current line below and moves the cursor down one row", ->
+          editor.moveCursorToBottom()
+          editor.insertNewline()
+          editor.moveCursorToBottom()
+          editor.trigger 'editor:duplicate-line'
+          expect(buffer.lineForRow(13)).toBe ''
+          expect(buffer.lineForRow(14)).toBe ''
+          expect(buffer.lineForRow(15)).toBeUndefined()
+          expect(editor.getCursorBufferPosition()).toEqual [14, 0]

src/app/edit-session.coffee

@@ -411,6 +411,28 @@ class EditSession
 
       @setSelectedBufferRange(selection.translate([1]), preserveFolds: true)
 
+  duplicateLine: ->
+    return unless @getSelection().isEmpty()
+
+    @transact =>
+      cursorPosition = @getCursorBufferPosition()
+      cursorRowFolded = @isFoldedAtCursorRow()
+      if cursorRowFolded
+        screenRow = @screenPositionForBufferPosition(cursorPosition).row
+        bufferRange = @bufferRangeForScreenRange([[screenRow], [screenRow + 1]])
+      else
+        bufferRange = new Range([cursorPosition.row], [cursorPosition.row + 1])
+
+      insertPosition = new Point(bufferRange.end.row)
+      if insertPosition.row >= @buffer.getLastRow()
+        @unfoldCurrentRow() if cursorRowFolded
+        @buffer.append("\n#{@getTextInBufferRange(bufferRange)}")
+        @foldCurrentRow() if cursorRowFolded
+      else
+        @buffer.insert(insertPosition, @getTextInBufferRange(bufferRange))
+
+      @setCursorScreenPosition(@getCursorScreenPosition().translate([1]))
+      @foldCurrentRow() if cursorRowFolded
 
   mutateSelectedText: (fn) ->
     @transact => fn(selection) for selection in @getSelections()

src/app/editor.coffee

@@ -186,6 +186,7 @@ class Editor extends View
         'editor:copy-path': @copyPathToPasteboard
         'editor:move-line-up': @moveLineUp
         'editor:move-line-down': @moveLineDown
+        'editor:duplicate-line': @duplicateLine
 
     documentation = {}
     for name, method of editorBindings
@@ -209,6 +210,7 @@ class Editor extends View
   moveCursorToEndOfLine: -> @activeEditSession.moveCursorToEndOfLine()
   moveLineUp: -> @activeEditSession.moveLineUp()
   moveLineDown: -> @activeEditSession.moveLineDown()
+  duplicateLine: -> @activeEditSession.duplicateLine()
   setCursorScreenPosition: (position) -> @activeEditSession.setCursorScreenPosition(position)
   getCursorScreenPosition: -> @activeEditSession.getCursorScreenPosition()
   getCursorScreenRow: -> @activeEditSession.getCursorScreenRow()

src/app/keymaps/editor.cson

@@ -40,3 +40,4 @@
   'ctrl-C': 'editor:copy-path'
   'ctrl-meta-up': 'editor:move-line-up'
   'ctrl-meta-down': 'editor:move-line-down'
+  'meta-D': 'editor:duplicate-line'