nix: add android ndk to derivation

Signed-off-by: markoburcul <marko@status.im>

default.nix

@@ -1,23 +0,0 @@
-{ 
-  pkgs,
-  target-platform ? "aarch64-android-prebuilt",
-}:
-
-pkgs.pkgsCross.${target-platform}.rustPlatform.buildRustPackage {
-  pname = "zerokit";
-  version = "nightly";
-
-  src = ./.;
-
-  cargoLock = {
-    lockFile = ./Cargo.lock;
-    allowBuiltinFetchGit = true;
-  };
-
-  CARGO_HOME = "/tmp";
-
-  meta = with pkgs.lib; {
-    description = "Zerokit";
-    license = licenses.mit;
-  };
-}

flake.nix

@@ -14,14 +14,29 @@
         "i686-windows"
       ];
       forAllSystems = nixpkgs.lib.genAttrs stableSystems;
-      pkgsFor = forAllSystems (system: import nixpkgs { inherit system; });
+      pkgsFor = forAllSystems (
+        system: import nixpkgs {
+          inherit system;
+          config = {
+            android_sdk.accept_license = true;
+            allowUnfree = true;
+          };
+          overlays =  [
+            (final: prev: {
+              androidEnvCustom = prev.callPackage ./nix/pkgs/android-sdk { };
+              androidPkgs = final.androidEnvCustom.pkgs;
+              androidShell = final.androidEnvCustom.shell;
+            })
+          ];
+        }
+      );
     in
     {
       packages = forAllSystems (system: let
         pkgs = pkgsFor.${system};
       in rec {
-        zerokit-android-arm64 = pkgs.callPackage ./default.nix { target-platform="aarch64-android-prebuilt"; };
-        zerokit-android-arm   = pkgs.callPackage ./default.nix { target-platform="armv7a-android-prebuilt"; };
+        zerokit-android-arm64 = pkgs.callPackage ./nix/default.nix { target-platform="aarch64-android"; rust-target= "aarch64-linux-android"; };
+        zerokit-android-arm   = pkgs.callPackage ./nix/default.nix { target-platform="x86_64-linux-android"; rust-target= "x86_64-linux-android"; };
         default = zerokit-android-arm64;
       });
     };

nix/default.nix

@@ -0,0 +1,36 @@
+{ 
+  pkgs,
+  target-platform ? "aarch64-android",
+  rust-target ? "aarch64-linux-android",
+}:
+
+pkgs.pkgsCross.${target-platform}.rustPlatform.buildRustPackage {
+  pname = "zerokit";
+  version = "nightly";
+
+  src = ../.;
+
+  cargoLock = {
+    lockFile = ../Cargo.lock;
+    allowBuiltinFetchGit = true;
+  };
+
+  ANDROID_NDK_HOME="${pkgs.androidPkgs.ndk}";
+  CARGO_HOME = "/tmp";
+
+  buildPhase = ''
+    pushd rln
+    cargo rustc --crate-type=cdylib --release --lib --target=${rust-target}
+    popd
+  '';
+
+  installPhase = ''
+    mkdir -p $out/build/
+    cp -r ./target/release/librln.so $out/build/
+  '';
+
+  meta = with pkgs.lib; {
+    description = "Zerokit";
+    license = licenses.mit;
+  };
+}

nix/pkgs/android-sdk/compose.nix

@@ -0,0 +1,26 @@
+#
+# This Nix expression centralizes the configuration
+# for the Android development environment.
+#
+
+{ androidenv, lib, stdenv }:
+
+assert lib.assertMsg (stdenv.system != "aarch64-darwin")
+  "aarch64-darwin not supported for Android SDK. Use: NIXPKGS_SYSTEM_OVERRIDE=x86_64-darwin";
+
+# The "android-sdk-license" license is accepted
+# by setting android_sdk.accept_license = true.
+androidenv.composeAndroidPackages {
+  cmdLineToolsVersion = "9.0";
+  toolsVersion = "26.1.1";
+  platformToolsVersion = "33.0.3";
+  buildToolsVersions = [ "34.0.0" ];
+  platformVersions = [ "34" ];
+  cmakeVersions = [ "3.22.1" ];
+  ndkVersion = "25.2.9519653";
+  includeNDK = true;
+  includeExtras = [
+    "extras;android;m2repository"
+    "extras;google;m2repository"
+  ];
+}

nix/pkgs/android-sdk/default.nix

@@ -0,0 +1,14 @@
+#
+# This Nix expression centralizes the configuration
+# for the Android development environment.
+#
+
+{ callPackage }:
+
+let
+  compose = callPackage ./compose.nix { };
+  pkgs = callPackage ./pkgs.nix { inherit compose; };
+  shell = callPackage ./shell.nix { androidPkgs = pkgs; };
+in {
+  inherit compose pkgs shell;
+}

nix/pkgs/android-sdk/pkgs.nix

@@ -0,0 +1,17 @@
+{ stdenv, compose }:
+
+#
+# This derivation simply symlinks some stuff to get
+# shorter paths as libexec/android-sdk is quite the mouthful.
+# With this you can just do `androidPkgs.sdk` and `androidPkgs.ndk`.
+#
+stdenv.mkDerivation {
+  name = "${compose.androidsdk.name}-mod";
+  phases = [ "symlinkPhase" ];
+  outputs = [ "out" "sdk" "ndk" ];
+  symlinkPhase = ''
+    ln -s ${compose.androidsdk} $out
+    ln -s ${compose.androidsdk}/libexec/android-sdk $sdk
+    ln -s ${compose.androidsdk}/libexec/android-sdk/ndk-bundle $ndk
+  '';
+}

nix/pkgs/android-sdk/shell.nix

@@ -0,0 +1,18 @@
+{ mkShell, openjdk, androidPkgs }:
+
+mkShell {
+  name = "android-sdk-shell";
+  buildInputs = [ openjdk ];
+
+  shellHook = ''
+    export ANDROID_HOME="${androidPkgs.sdk}"
+    export ANDROID_NDK_ROOT="${androidPkgs.ndk}"
+    export ANDROID_SDK_ROOT="$ANDROID_HOME"
+
+    export PATH="$ANDROID_NDK_ROOT:$PATH"
+    export PATH="$ANDROID_SDK_ROOT/tools:$PATH"
+    export PATH="$ANDROID_SDK_ROOT/tools/bin:$PATH"
+    export PATH="$(echo $ANDROID_SDK_ROOT/cmdline-tools/*/bin):$PATH"
+    export PATH="$ANDROID_SDK_ROOT/platform-tools:$PATH"
+  '';
+}